Rest Docs 기능 활성을 위해 build.gradle 파일에 코드를 추가하고 build 하니까 자꾸만 찾을 수 없다고 떠서 이번 기회에 build.gradle 에 추가해야 하는 코드를 정리해 놓으려고 한다.

버전 정보는 바뀔 수 있으므로 불러오기에 실패할 경우 버전을 체크하자.

plugins {
	id 'org.springframework.boot' version '2.7.2'
	id 'io.spring.dependency-management' version '1.0.12.RELEASE'
	id 'org.asciidoctor.jvm.convert' version '3.3.2'
	id 'java'
}

group = 'com.wisejade'		// initializr에서 프로젝트 생성시 설정한 group이 자동으로 들어감
version = '0.0.1-SNAPSHOT'
sourceCompatibility = '11'

repositories {
	mavenCentral()
}


ext {
	set('snippetsDir', file("build/generated-snippets"))	// 추가해야하는 코드
}

configurations {
	asciidoctorExtensions		// asciidoctorExtensions를 사용하기 위해 추가
}

dependencies {
	testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'	// mockmvc 사용을 위해 추가
	asciidoctorExtensions 'org.springframework.restdocs:spring-restdocs-asciidoctor'	// asciidoctor
	implementation 'org.springframework.boot:spring-boot-starter-data-jpa'	// Spring data jpa 사용을 위해 추가
	implementation 'org.springframework.boot:spring-boot-starter-validation'
	implementation 'org.springframework.boot:spring-boot-starter-web'
	compileOnly 'org.projectlombok:lombok'
	runtimeOnly 'com.h2database:h2'
	annotationProcessor 'org.projectlombok:lombok'
	testImplementation 'org.springframework.boot:spring-boot-starter-test'
	implementation 'org.mapstruct:mapstruct:1.5.2.Final'					// mapstruct 사용을 위해 추가
	annotationProcessor 'org.mapstruct:mapstruct-processor:1.5.1.Final'		// mapstruct 사용을 위해 추가
	implementation 'org.springframework.boot:spring-boot-starter-mail'

	implementation 'com.google.code.gson:gson'	// gson은 Json을 String으로 쉽게 바꿔줌
}

tasks.named('test') {	// 추가해야하는 코드
	outputs.dir snippetsDir
	useJUnitPlatform()
}

tasks.named('asciidoctor') {	// 추가해야하는 코드
	configurations "asciidoctorExtensions"
	inputs.dir snippetsDir
	dependsOn test
}

task copyDocument(type: Copy) {	// 생성된 rest docs를 static/docs로 자동으로 copy
	dependsOn asciidoctor
	from file("${asciidoctor.outputDir}")
	into file("src/main/resources/static/docs")
}

build {	// task build 할 때마다 copy
	dependsOn copyDocument
}

bootJar {
	dependsOn copyDocument
	from("${asciidoctor.outputDir}") {
		into 'static/docs'
	}
}

SpringBoot에서 JPA를 사용할 때

application.yml 또는 application.properties 파일에서 설정을 해주어야 한다.

ddl-auto는 JPA 설정중에 빌드시 JPA가 어떻게 자동으로 테이블을 생성해줄지에 대한 설정을 지정한다.

➤ ddl-auto 옵션 종류

• create: 기존테이블 삭제 후 다시 생성 (DROP + CREATE)
• create-drop: 테이블 생성 후 종료시점에 테이블 DROP
• update: 변경분만 반영(운영DB에서는 사용하면 안됨)
• validate: 엔티티와 테이블이 정상 매핑되었는지만 확인
• none: 사용하지 않음(사실상 없는 값이지만 관례상 none이라고 한다.)

⚠️ 주의사항

• 운영 장비에서는 절대 crate, create-drop, update를 사용하면 안된다.
• create는 로컬환경에서만 사용한다
• 개발 초기 단계에는 create 또는 update 를 사용한다.
• 테스트 서버는 update 또는 validate 를 사용한다.
• 스테이징과 운영 서버는 validate 또는 none 을 사용한다.

출처 : https://smpark1020.tistory.com/140